Adam;

T-SQL cursors are used to implement the TradeUpdate transactions, TradeOrder transactions, TradeLookup transactions, MarketWatch transactions, and MarkeFeed transactions. Here's one of the TransUpdate stored procedures:

-- Trade Update Frame 3 returns up to max_trades trades for a given

-- security symbol on or after a specified point in time.

-- It may also modify up to max_updates rows of CASH_TRANSACTION.

--

CREATE  PROCEDURE   TradeUpdateFrame3

                       @max_trades         int,

                       @max_updates        int,

                       @symbol             varchar(15),

                       @start_trade_dts    datetime,

                       @end_trade_dts      datetime,

                       @max_acct_id        IDENT_T

AS

BEGIN

   SET TRANSACTION ISOLATION LEVEL REPEATABLE READ

BEGIN TRANSACTION

   DECLARE @trade_id           TRADE_T,

           @t_ca_id            IDENT_T,

           @t_exec_name        varchar(64),

           @t_is_cash          TPCE_BOOLEAN,

           @t_trade_price      S_PRICE_T,

           @t_qty              S_QTY_T,

           @t_dts              datetime,

           @t_tt_id            char(3),

           @se_cash_type       varchar(40),

           @se_cash_due_date   datetime,

           @se_amount          VALUE_T,

           @ct_amount          VALUE_T,

           @ct_name            varchar(100),

           @ct_dts             datetime,

           @num_found          int,

           @num_updated        int,

           @ct_string          varchar(20),

           @s_name             varchar(70),

           @type_name          char(12)

   DECLARE Trade_List CURSOR LOCAL FORWARD_ONLY SCROLL_LOCKS

               FOR SELECT  TOP 20

                           T_ID,

                           T_CA_ID,

                           T_EXEC_NAME,

                           T_IS_CASH,

                           T_TRADE_PRICE,

                           T_QTY,

                           T_DTS,

                           T_TT_ID

                   FROM    TRADE

                   WHERE   T_S_SYMB    =  @symbol AND

                           T_DTS       BETWEEN @start_trade_dts AND @end_trade_dts

                   ORDER   BY T_DTS

   SELECT  @num_found      = 0,

           @num_updated    = 0

   SELECT  @s_name = S_NAME

   FROM    SECURITY

   WHERE   S_SYMB  = @symbol

   OPEN    Trade_List

   FETCH FROM  Trade_List

         INTO  @trade_id,

               @t_ca_id,

               @t_exec_name,

               @t_is_cash,

               @t_trade_price,

               @t_qty,

               @t_dts,

               @t_tt_id

   WHILE (@@FETCH_STATUS = 0 AND @max_trades > 0)

   BEGIN

       -- set cash transaction local variables to NULL

       SELECT  @ct_amount  = NULL,

               @ct_name    = NULL,

               @ct_dts     = NULL,

               @num_found  = @num_found + 1,

               @max_trades = @max_trades - 1,

               @type_name  = TT_NAME

       FROM    TRADE_TYPE

       WHERE   TT_ID       = @t_tt_id

       SELECT  @se_cash_type       = SE_CASH_TYPE,

               @se_cash_due_date   = SE_CASH_DUE_DATE,

               @se_amount          = SE_AMT

       FROM    SETTLEMENT

       WHERE   SE_T_ID             = @trade_id

       -- if this is a cash transaction

       -- get information from CASH_TRANSACTION

       IF (@t_is_cash <> 0)

       BEGIN

           IF (@num_updated < @max_updates)

           BEGIN

               SELECT  @ct_string  = RTRIM(RTRIM(@type_name) + ' ' + LTRIM(CAST(@t_qty AS char(6))))

               UPDATE  CASH_TRANSACTION

               SET     CT_NAME = CASE  WHEN CT_NAME LIKE '% Shares of %' THEN @ct_string + ' shares of ' + RTRIM(@s_name)

                                       WHEN CT_NAME LIKE '% shares of %' THEN @ct_string + ' Shares of ' + RTRIM(@s_name)

                                       ELSE CT_NAME

                                 END

               WHERE   CT_T_ID = @trade_id

               SET     @num_updated    = @num_updated + @@ROWCOUNT

           END

           SELECT  @ct_amount  = CT_AMT,

                   @ct_name    = CT_NAME,

                   @ct_dts     = CT_DTS

           FROM    CASH_TRANSACTION

           WHERE   CT_T_ID     = @trade_id

       END

       -- return as a rowset

       SELECT  @t_ca_id,

               @ct_amount,

               @ct_dts,

               @ct_name,

               @t_exec_name,

               @t_is_cash,

               @t_trade_price,

               @t_qty,

               @s_name,

               @se_amount,

               @se_cash_due_date,

               @se_cash_type,

               @t_dts,

               @trade_id,

               @t_tt_id,

               @type_name

       -- get the trade history of 2-3 rows for this trade

       SELECT  TOP 3

               TH_DTS,

               TH_ST_ID

       FROM    TRADE_HISTORY

       WHERE   TH_T_ID = @trade_id

       ORDER   BY TH_DTS

       IF (@max_trades > 0)

           FETCH FROM  Trade_List

                 INTO  @trade_id,

                       @t_ca_id,

                       @t_exec_name,

                       @t_is_cash,

                       @t_trade_price,

                       @t_qty,

                       @t_dts,

                       @t_tt_id

   END

   SELECT  @num_found,

           @num_updated

   CLOSE       Trade_List

   DEALLOCATE  Trade_List

   COMMIT TRANSACTION

END

GO

You can look up others on www.tpc.org.